grails install-plugin easyb

grailsTest "controller", "NameOfControllerClass"

/**
 * introduced by Jeffrey C. Erikson
 */
scenario "we should be able to inject services", {
	when "requesting the author service bean", {
		inject "authorService"
	}
	then "author service should be callable", {
		authorService.doSomething(3).shouldBe "burp"
	}
}
scenario "non existent beans should fail", {
	when "we have a request for a non-existent bean", {
		beanReq = { 
			inject "wibble"
		}
	}
	then "it should fail", {
		ensureThrows(Exception) {
			beanReq.call()
		}
	}
}

class SearchController {
    def ldapService
    def index = {
	def result = [:]
        if (!params.query?.trim()) {
                return result
        }
        try {
		if(params.user) {
			result.searchResult = User.findByLastname(params.query, params)
		} else {
			result.searchResult = ldapService.search(params.query, params)
		}
        } catch (Throwable t) {
		log.error("Error while performing search", t)
		result.searchResult = null
		result.exception = true
        }
	return result
    }
}

scenario "Search controller returns results of a ldap search", {
	given "Controller is instantiated", {
		mockController SearchController
		controller = new SearchController()
		ldapService = mockFor(LdapService)		
		ldapService.metaClass.search = { String param, Map params  ->
			def searchResult = [:]
			searchResult.total = 2
			searchResult.max = 10
			searchResult.offset = 0
			searchResult.results = [new User(name: "Test 1"), new User(name: "Test 2")]
			return searchResult
		}		
		controller.ldapService = ldapService
	}
	when "controller receives request for index action"
	and "a search parameter is included", {
		controller.params.query = "Smith"
		result = controller.index()
	}
	then "controller display search page", {
		controller.redirectArgs.view.shouldBe null
	}
	and "controller returns a list of search results", {
		result.searchResult.total.shouldBe 2
		result.searchResult.max.shouldBe 10
		result.searchResult.results.size().shouldBe 2
	}
}
scenario "Search controller responds to a User search", {
	given "Controller is instantiated", {
		mockController SearchController	
		User.metaClass.static.findByLastname = { String param, Map params  ->
			def searchResult = [:]			
			searchResult.total = 2
			searchResult.max = 10
			searchResult.offset = 0
			searchResult.results = [new User(name: "Test 1"), new User(name: "Test2")]
			return searchResult
		}		
		controller = new SearchController()
	}		
	when "controller receives request for index action"
	and "a search parameter ‘Smith’ is included", { controller.params.query = "Smith" }
	and "user search parameter is included", {
		controller.params.user = "t"
		result = controller.index()				
	}
	then "controller displays search page", {
		controller.redirectArgs.view.shouldBe null		
	}
	and "controller returns a list of search results", {
		result.searchResult.total.shouldBe 2
		result.searchResult.max.shouldBe 10
		result.searchResult.results.size().shouldBe 2
	}
}
scenario "Search controller responds to index request without search parameter", {
	given "Controller is instantiated", {
		mockController SearchController
		controller = new SearchController()
	}
	when "controller receives request for index action"
	and "no search parameter is passed", {
		result = controller.index()
	}
	then "controller displays search page", {
		controller.redirectArgs.view.shouldBe null
	}
	and "controller should return null search results", {
		result.searchResult.shouldBe null
	}
}
scenario "Search controller handles exception when performing search", {
	given "Controller is instantiated", {
		mockController SearchController
		controller = new SearchController()
		ldapService = mockFor(LdapService)		
		ldapService.metaClass.search = { String param, Map params  ->
			throw new Exception("Search Exception")
		}		
		controller.ldapService = ldapService		
	}
	when "controller receives request for index action"
	and "search parameter 'Smith' is passed", {
		controller.params.query = "Smith"
		result = controller.index()
	}
	then "controller indicates exception was thrown", {
		result.exception.shouldBe true
	}
	and "controller should return null search results", {
		result.searchResult.shouldBe null
	}
}